Visual Basic - Technik, FAQ, Tricks, Beispiele

Home / System / Datei / UNC

Netzlaufwerke, UNC- und Server-Pfade

Historie
05.12.2001IsServerPath für Netzlaufwerke
08.07.2001Code für UNCPath optimiert; Umkehrfunktion DrivePath hinzugefügt
02.05.2000Erste Version: Laufwerks- nach UNC-Pfad

Einleitung

Sogenannte "UNC-Pfade" kommen immer dann ins Spiel, wenn Ressourcen im Netz (auf einem "File-Server") benutzt werden sollen. Einem öfter benötigtem Server-Verzeichnis wird der Einfachheit halber oft ein Laufwerk zugeordnet (z.B. als "Arbeitsgruppen-Laufwerk", im Beispiel W:). Dann kann z.B. statt mit der unübersichtlichen UNC-Notation \\FileSvr2\WebAG\Infos\ einfach über ein "virtuelles" Laufwerk zugegriffen werden: W:\Infos\

Unten werden zwei Funktionen vorgestellt, welche gerade die Umwandlung zwischen UNC- und Laufwerks-Pfad erlauben. Außerdem wird gezeigt, wie man dank UNC-Notation sicher feststellt, ob sich ein bestimmtes Verzeichnis lokal oder auf einem Netzlaufwerk befindet.

Code: Netzlaufwerk - Ja oder Nein?

Mit Hilfe der unten gezeigten UNCPath-Funktion kann leicht eine Funktion realisiert werden, welche angibt, ob ein bestimmter Pfad lokal oder auf einem Server liegt. Beginnt der UNC-Pfad mit zwei Backslashs ("\\"), dann handelt es sich um eine Netzressource:

Public Function IsServerPath(ByVal Path As String) As Boolean
  IsServerPath = (Left$(UNCPath(Path, True), 2) = "\\")
End Function

Im Gegensatz zu der im Artikel "CDROM, Harddisk, oder was?" gezeigten Methode, funktioniert IsServerPath auch unter ungewöhnlichen Umgebungen.

Code: Laufwerks- nach UNC-Pfad

Im Deklarationsteil eines Moduls muss folgende API-Funktion bekannt gemacht werden:

Private Declare Function WNetGetConnectionA Lib "mpr.dll" ( _
    ByVal lpszLocalName As String, _
    ByVal lpszRemoteName As String, _
    cbRemoteName As Long) As Long

Die folgende Funktion nutzt die o.g. API-Routine, wobei der ggf. angehängte Pfad besonders behandelt wird. Wird ein unbekanntes Laufwerk angegeben, so wird eine entsprechende Fehlermeldung zurückgegeben (kann mit IgnoreErrors = True unterdrückt werden).

Public Function UNCPath(ByVal Path As String, _
    Optional IgnoreErrors As Boolean = False) As String
  Dim UNC As String * 512
  
  If Len(Path) = 1 Then Path = Path & ":"
  If Right$(Path, 1) <> "\" Then Path = Path & "\"
  If WNetGetConnectionA(Left$(Path, 2), UNC, Len(UNC)) Then

    'API-Routine gibt Fehler zurück:
    If IgnoreErrors Then
      UNCPath = Path
    Else
      Err.Raise 5 'Invalid procedure call or argument
    End If

  Else

    'Ergebnis zurückgeben:
    UNCPath = Left$(UNC, InStr(UNC, vbNullChar) - 1) _
            & Mid$(Path, 3)

  End If
End Function

Code: UNC- nach Laufwerks-Pfad

Die Umkehrfunktion benutzt die in "Laufwerke nach einer bestimmten Datei durchsuchen" vorgestellte LogicalDrives-Funktion, um alle Laufwerke nach und nach in UNC umzuwandeln. Bei Übereinstimmung mit dem gesuchten UNC wird das entsprechende Ergebnis zurückgegeben. Existiert kein Laufwerk für den angegebenen UNC-Pfad, so wird eine entsprechende Fehlermeldung zurückgegeben (kann mit IgnoreErrors = True unterdrückt werden).

Public Function DrivePath(ByVal Path As String, _
    Optional IgnoreErrors As Boolean = False) As String
  Dim Drive As Variant
  Dim UNC As String
  
  'Alle Laufwerke durchsuchen:
  If Right$(Path, 1) <> "\" Then Path = Path & "\"
  For Each Drive In LogicalDrives()
    UNC = UNCPath(Drive, True)
    If InStr(1, Path, UNC, vbTextCompare) = 1 Then Exit For
  Next Drive
  
  If IsEmpty(Drive) Then

    'Kein Laufwerk für UNC gefunden:
    If IgnoreErrors Then
      DrivePath = Path
    Else
      Err.Raise 5 'Invalid procedure call or argument
    End If

  Else

    'Ergebnis zurückgeben:
    DrivePath = Drive & Mid$(Path, Len(UNC))

  End If
End Function

© Jost Schwider, 30.04.2000-05.12.2001 - http://vb-tec.de/uncpfad.htm