VB-Tec.de Visual Basic - Technik, FAQ, Tricks, Beispiele

Historie
01.11.2001	erst Wochentipp (8.-14.10.), dann sogar Monatstipp Oktober
09.11.2000	Erste Version

Traditionelles Vorgehen

Wenn vor dem Füllen eines Arrays nicht die benötigte Größe bekannt ist, wird oft folgende Vorgehensweise benutzt, um via ReDim Preserve dynamisch neuen Speicherplatz zu schaffen:

Private Sub FillArraySlow()
  Dim ElemArray() As Long
  Dim ElemCount As Long
  Dim Elem As Long
  Dim i As Long
  
  For i = 1 To 1000000 '...eigentlich unbekannt
    'Elem berechnen/bestimmen:
    Elem = 123 '...nur Test
    
    'Array vergrößern:
    ElemCount = ElemCount + 1
    ReDim Preserve ElemArray(ElemCount)
    
    'Element ablegen:
    ElemArray(ElemCount) = Elem
  Next i
End Sub

Dieses Vorgehen hat jedoch einige Einschränkungen: Es ist sehr Zeitaufwendig (bei mir etwa 16,7s), weil VB bei jedem Element neuen Speicher anlegen sowie alle bisherigen Daten kopieren muss. Ausserdem wird der Speicher u.U. sehr fragmentiert, was (z.B. bei Windows98) zu einer obskuren Fehlermeldung "Nicht genügend Speicher" führen kann.

Optimales Vorgehen

Daher benutze ich in meinen Projekten gerne folgende Vorgehensweise, die bei jeder notwendigen Vergrößerung gleich den doppelten Speicherplatz reserviert:

Private Sub FillArrayFast()
  Dim ElemArray() As Long
  Dim ElemCount As Long
  Dim ElemUBound As Long
  Dim Elem As Long
  Dim i As Long
  
  For i = 1 To 1000000 '...eigentlich unbekannt
    'Elem berechnen/bestimmen:
    Elem = 123 '...nur Test
    
    'Array-Größe ggf. verdoppeln:
    ElemCount = ElemCount + 1
    If ElemCount > ElemUBound Then
      ElemUBound = 2 * ElemCount
      ReDim Preserve ElemArray(ElemUBound)
    End If
    
    'Element ablegen:
    ElemArray(ElemCount) = Elem
  Next i
  
  'Überflüssigen Speicher freigeben:
  ReDim Preserve ElemArray(ElemCount)
End Sub

VB muss also viel seltener Speicherbereiche reservieren und kopieren. Dadurch wird der gesamte Vorgang deutlich beschleunigt (bei mir nur noch 0,08s, also Faktor 200!) und die Speicher-Fragmentierung ist vernachlässigbar.

Selbst die optimale Lösung (die Anzahl ist vorher genau bekannt und das Array wird nur einmal passend dimensioniert) ist kaum schneller (bei mir etwa 0,05s)!